MacFormat 1994 November/macformat-018.iso/Comms Spectacular/AppleTalk Remote Access/ara-various-scripts folder/MicroCom MacModem V.32/MicroCom MacModem V.32

Text File | 1991-09-04 | 3.2 KB | 211 lines | [mlts/slnk]

! "Microcom QX - 6/28/91"
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 9600, 0, 8, 1
!
! first sync up the modem
!
matchclr
matchstr 1 3 "A"
settries 0
@LABEL 2
write "A"
matchread 10
inctries
iftries 4 3
jump 2
@LABEL 3
matchclr
settries 0
matchstr 1 4 "OK\13\10"
write "T\13"
matchread 30
!
!    Now, recall the modems factory configuration
!
@LABEL 4
matchstr 1 5 "OK\13\10"
write "AT&F\13"
matchread 30
inctries
iftries 2 59
! Modem is not responding, reset
DTRClear
pause 5
DTRSet
jump 4
!
! Next, Set up the configuration:
! Echo off, serial port flow control off, modem flow control off
!
@LABEL 5
matchstr 1 6 "OK\13\10"
write "ATE0\\Q0\\G0\13"
matchread 30
jump 59
!
! Connect in direct mode, no mnp, no speed conversion; go on hook and reset when DTR drops
!
@LABEL 6
matchstr 1 7 "OK\13\10"
write "AT\\N1&D3\13"
matchread 30
jump 59
!
! Set up the speaker: If speaker flag is "1", jump to 8;  else turn off speaker
!
@LABEL 7
ifstr 2 8 "1"
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready.  So enable answering, or originate a call
!
@LABEL 8
ifANSWER 30
note "Dialing ^1" 3
write "ATS0=0DT^1\13"
!
@LABEL 9
matchstr 1 11 "CONNECT 1200\13\10"
matchstr 2 12 "CONNECT 2400\13\10"
matchstr 3 13 "CONNECT 4800\13\10"
matchstr 4 14 "CONNECT 9600\13\10"
matchstr 5 50 "NO CARRIER\13\10"
matchstr 6 50 "ERROR\13\10"
matchstr 7 52 "NO DIALTONE\13\10"
matchstr 8 53 "BUSY\13\10"
matchstr 9 54 "NO ANSWER\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Communicating at 1200 bps." 2
serreset 1200, 0, 8, 1
jump 15
!
@LABEL 12
note "Communicating at 2400 bps." 2
serreset 2400, 0, 8, 1
jump 15
!
@LABEL 13
note "Communicating at 4800 bps." 2
serreset 4800, 0, 8, 1
jump 15
!
@LABEL 14
note "Communicating at 9600 bps." 2
serreset 9600, 0, 8, 1
!
@LABEL 15
ifANSWER 16
pause 30
@LABEL 16
exit 0
!
! @ANSWER
! Set up the modem to answer
@LABEL 30
write "ATS0=1\13"
matchstr 1 31 "OK\13\10"
matchread 30
jump 59
!
@LABEL 31
matchstr 1  32 "RING\13\10"
matchstr 2  11 "CONNECT 1200\13\10"
matchstr 3  12 "CONNECT 2400\13\10"
matchstr 4  13 "CONNECT 4800\13\10"
matchstr 5  14 "CONNECT 9600\13\10"
matchstr 6  50 "NO CARRIER\13\10"
matchstr 7  50 "ERROR\13\10"
matchstr 8  52 "NO DIALTONE\13\10"
matchstr 9  53 "BUSY\13\10"
matchstr 10 54 "NO ANSWER\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone…" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
@LABEL 61
write "ATH\13"
matchclr
matchstr 1 63 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
matchstr 3 63 "ERROR\13\10"
matchread 30
inctries
iftries 3 63
! no response, try escape sequence
write "+++"
matchclr
matchstr 1 62 "OK\13\10"
matchread 20
!
! No response from modem, toggle DTR
!
DTRClear
pause 5
DTRSet
jump 61
!
@LABEL 62
pause 5
write "ATH\13"
matchstr 1 63 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
matchstr 3 63 "ERROR\13\10"
matchread 70
jump 61
!
! Recall factory settings
!
@LABEL 63
pause 5
matchclr
matchstr 1 64 "OK\13\10"
write "AT&F\13"
matchread 30
!
! Turn off auto answer
!
@LABEL 64
write "ATS0=0\13"
matchstr 1 65 "OK\13\10"
matchread 30
!
! Add delay to make sure other side of connection hangs up for call back.
!
@LABEL 65
exit 0